feat: init

provisioning/django-allauth-cas/01-setup.patch

@@ -0,0 +1,12 @@
+diff --git a/setup.py b/setup.py
+index fb06ec0..506677f 100644
+--- a/setup.py
++++ b/setup.py
+@@ -52,7 +52,6 @@ setup(
+     install_requires=[
+         "django-allauth",
+         "python-cas",
+-        "six",
+     ],
+     extras_require={
+         "docs": ["sphinx"],

provisioning/django-allauth-cas/02-registry.patch

@@ -0,0 +1,39 @@
+diff --git a/allauth_cas/signals.py b/allauth_cas/signals.py
+index 36c9b24..530c26e 100644
+--- a/allauth_cas/signals.py
++++ b/allauth_cas/signals.py
+@@ -1,4 +1,4 @@
+-from allauth.account.adapter import get_adapter
++from allauth.socialaccount.adapter import get_adapter
+ from allauth.account.utils import get_next_redirect_url
+ from allauth.socialaccount import providers
+ from django.contrib.auth.signals import user_logged_out
+@@ -14,7 +14,7 @@ def cas_account_logout(sender, request, **kwargs):
+     if not provider_id:
+         return
+ 
+-    provider = providers.registry.by_id(provider_id, request)
++    provider = get_adapter(request).get_provider(request, provider_id)
+ 
+     if not provider.message_suggest_caslogout_on_logout(request):
+         return
+diff --git a/allauth_cas/views.py b/allauth_cas/views.py
+index d08e354..9e81e53 100644
+--- a/allauth_cas/views.py
++++ b/allauth_cas/views.py
+@@ -1,5 +1,5 @@
+ import cas
+-from allauth.account.adapter import get_adapter
++from allauth.socialaccount.adapter import get_adapter
+ from allauth.account.utils import get_next_redirect_url
+ from allauth.socialaccount import providers
+ from allauth.socialaccount.helpers import (
+@@ -56,7 +56,7 @@ class CASAdapter:
+         """
+         Returns a provider instance for the current request.
+         """
+-        return providers.registry.by_id(self.provider_id, self.request)
++        return get_adapter(self.request).get_provider(self.request, self.provider_id)
+ 
+     def complete_login(self, request, response):
+         """

provisioning/django-allauth-cas/default.nix

@@ -0,0 +1,51 @@
+# SPDX-FileCopyrightText: 2025 Tom Hubrecht <tom.hubrecht@dgnum.eu>
+#
+# SPDX-License-Identifier: EUPL-1.2
+
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  wheel,
+  django-allauth,
+  python-cas,
+}:
+
+buildPythonPackage rec {
+  pname = "django-allauth-cas";
+  version = "unstable-2024-01-25";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "jlucasp25";
+    repo = "django-allauth-cas";
+    rev = "77e02f3796cd564a9a0c48b5b568b14d4d4c5687";
+    hash = "sha256-y/IquXl/4+9MJmsgbWtPun3tBbRJ4kJFzWo5c+5WeHk=";
+  };
+
+  patches = [
+    ./01-setup.patch
+    ./02-registry.patch
+  ];
+
+  build-system = [
+    setuptools
+    wheel
+  ];
+
+  dependencies = [
+    django-allauth
+    python-cas
+  ];
+
+  pythonImportsCheck = [ "allauth_cas" ];
+
+  meta = {
+    description = "CAS support for django-allauth";
+    homepage = "https://github.com/jlucasp25/django-allauth-cas";
+    changelog = "https://github.com/jlucasp25/django-allauth-cas/blob/${src.rev}/CHANGELOG.rst";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ ];
+  };
+}

provisioning/django-browser-reload/default.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  wheel,
+  asgiref,
+  django,
+}:
+
+buildPythonPackage rec {
+  pname = "django-browser-reload";
+  version = "1.18.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "adamchainz";
+    repo = "django-browser-reload";
+    rev = version;
+    hash = "sha256-iLu9+E3Ejp/Dhv4I7RuL/F1WNiFRKytNvNDDhrh0Hhs=";
+  };
+
+  nativeBuildInputs = [
+    setuptools
+    wheel
+  ];
+
+  propagatedBuildInputs = [
+    asgiref
+    django
+  ];
+
+  pythonImportsCheck = [ "django_browser_reload" ];
+
+  meta = with lib; {
+    description = "Automatically reload your browser in development";
+    homepage = "https://github.com/adamchainz/django-browser-reload";
+    changelog = "https://github.com/adamchainz/django-browser-reload/blob/${src.rev}/CHANGELOG.rst";
+    license = licenses.mit;
+    maintainers = with maintainers; [ thubrecht ];
+  };
+}

provisioning/python-cas/default.nix

@@ -0,0 +1,49 @@
+# SPDX-FileCopyrightText: 2025 Tom Hubrecht <tom.hubrecht@dgnum.eu>
+#
+# SPDX-License-Identifier: EUPL-1.2
+
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  wheel,
+  lxml,
+  requests,
+  six,
+}:
+
+buildPythonPackage rec {
+  pname = "python-cas";
+  version = "1.6.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "python-cas";
+    repo = "python-cas";
+    rev = "v${version}";
+    hash = "sha256-0lpjG/Sma0tJGtahiFE1CjvTyswrBUp+F6f1S65b+lk=";
+  };
+
+  nativeBuildInputs = [
+    setuptools
+    wheel
+  ];
+
+  propagatedBuildInputs = [
+    lxml
+    requests
+    six
+  ];
+
+  pythonImportsCheck = [ "cas" ];
+
+  meta = with lib; {
+    description = "Python CAS (Central Authentication Service) client library support CAS 1.0/2.0/3.0";
+    homepage = "https://github.com/python-cas/python-cas";
+    license = licenses.mit;
+    maintainers = with maintainers; [
+      # thubrecht
+    ];
+  };
+}

provisioning/shell.nix

@@ -0,0 +1,71 @@
+{
+  sources ? import ../npins,
+  pkgs ? import sources.nixpkgs { },
+}:
+
+let
+  check = (import sources.git-hooks).run {
+    src = ./.;
+
+    hooks = {
+      # JS hooks
+      # eslint.enable = true;
+
+      # Python hooks
+      ruff.enable = true;
+      black.enable = true;
+      isort.enable = true;
+
+      # Nix Hooks
+      statix.enable = true;
+      deadnix.enable = true;
+      rfc101 = {
+        enable = true;
+
+        name = "RFC-101 formatting";
+        entry = "${pkgs.lib.getExe pkgs.nixfmt-rfc-style}";
+        files = "\\.nix$";
+      };
+
+      # Misc Hooks
+      commitizen.enable = true;
+    };
+  };
+  python = pkgs.python3.override {
+    packageOverrides = self: _: {
+      python-cas = self.callPackage ./python-cas { };
+      django-allauth-cas = self.callPackage ./django-allauth-cas { };
+      django-browser-reload = self.callPackage ./django-browser-reload { };
+    };
+  };
+in
+pkgs.mkShell {
+  buildInputs = [
+    pkgs.jq
+    pkgs.dart-sass
+
+    (python.withPackages (
+      ps:
+      [
+        ps.django
+        ps.gunicorn
+        ps.django-browser-reload
+        ps.django-types
+        ps.django-allauth-cas
+        ps.django-allauth
+
+        #Debug
+        ps.black
+        ps.isort
+      ]
+      ++ ps.django-allauth.optional-dependencies.socialaccount
+    ))
+
+    pkgs.djlint
+  ]
+  ++ check.enabledPackages;
+  shellHook = ''
+    ${check.shellHook}
+  '';
+
+}