maurice/snix
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions

chore(snix): s/tvix/snix/

Browse source 
Change-Id: Iae961416eea0a38bc57df7b736f6dda5903b0828
This commit is contained in:
Florian Klink 2025-03-16 17:55:12 +00:00
parent 768f053416
commit 36e4d017f5
1417 changed files with 3741 additions and 3650 deletions
Download patch file Download diff file Expand all files Collapse all files

161
snix/utils.nix Normal file
View file

@ -0,0 +1,161 @@
{ pkgs, lib, depot, ... }:
{
mkFeaturePowerset = { crateName, features, override ? { } }:
let
powerset = xs:
let
addElement = set: element:
set ++ map (e: [ element ] ++ e) set;
in
lib.foldl' addElement [ [ ] ] xs;
in
lib.listToAttrs (map
(featuresPowerset: {
name = if featuresPowerset != [ ] then "with-features-${lib.concatStringsSep "-" featuresPowerset}" else "no-features";
value = depot.snix.crates.workspaceMembers.${crateName}.build.override (old: {
runTests = true;
features = featuresPowerset;
} // (if lib.isFunction override then override old else override)
);
})
(powerset features));
# Filters the given source, only keeping files related to the build, preventing unnecessary rebuilds.
# Includes src in the root, all other .rs files and optionally Cargo specific files.
# Additional files to be included can be specified in extraFileset.
filterRustCrateSrc =
{ root # The original src
, extraFileset ? null # Additional filesets to include (e.g. fileFilter for proto files)
, cargoSupport ? false
}:
lib.fileset.toSource {
inherit root;
fileset = lib.fileset.intersection
(lib.fileset.fromSource root) # We build our final fileset from the original src
(lib.fileset.unions ([
(lib.fileset.maybeMissing (root + "/src")) # src may be missing if the crate just has tests for example
(lib.fileset.fileFilter (f: f.hasExt "rs") root)
] ++ lib.optionals cargoSupport [
(lib.fileset.fileFilter (f: f.name == "Cargo.toml") root)
(lib.fileset.maybeMissing (root + "/Cargo.lock"))
] ++ lib.optional (extraFileset != null) extraFileset));
};
# A function which takes a pkgs instance and returns an overriden defaultCrateOverrides with support for snix crates.
# This can be used throughout the rest of the repo.
defaultCrateOverridesForPkgs = pkgs:
let
commonDarwinDeps = with pkgs.darwin.apple_sdk.frameworks; [
Security
SystemConfiguration
];
in
pkgs.defaultCrateOverrides // {
nar-bridge = prev: {
src = depot.snix.utils.filterRustCrateSrc { root = prev.src.origSrc; };
};
nix-compat = prev: {
src = depot.snix.utils.filterRustCrateSrc rec {
root = prev.src.origSrc;
extraFileset = root + "/testdata";
};
};
nix-compat-derive = prev: {
src = depot.snix.utils.filterRustCrateSrc { root = prev.src.origSrc; };
};
nix-compat-derive-tests = prev: {
src = depot.snix.utils.filterRustCrateSrc { root = prev.src.origSrc; };
};
snix-build = prev: {
src = depot.snix.utils.filterRustCrateSrc rec {
root = prev.src.origSrc;
extraFileset = lib.fileset.fileFilter (f: f.hasExt "proto") root;
};
PROTO_ROOT = depot.snix.build.protos.protos;
nativeBuildInputs = [ pkgs.protobuf ];
buildInputs = lib.optional pkgs.stdenv.isDarwin commonDarwinDeps;
SNIX_BUILD_SANDBOX_SHELL = if pkgs.stdenv.isLinux then pkgs.pkgsStatic.busybox + "/bin/sh" else "/bin/sh";
};
snix-castore = prev: {
src = depot.snix.utils.filterRustCrateSrc rec {
root = prev.src.origSrc;
extraFileset = lib.fileset.fileFilter (f: f.hasExt "proto") root;
};
PROTO_ROOT = depot.snix.castore.protos.protos;
nativeBuildInputs = [ pkgs.protobuf ];
};
snix-cli = prev: {
src = depot.snix.utils.filterRustCrateSrc rec {
root = prev.src.origSrc;
extraFileset = root + "/tests";
};
buildInputs = lib.optional pkgs.stdenv.isDarwin commonDarwinDeps;
};
snix-store = prev: {
src = depot.snix.utils.filterRustCrateSrc rec {
root = prev.src.origSrc;
extraFileset = lib.fileset.fileFilter (f: f.hasExt "proto") root;
};
PROTO_ROOT = depot.snix.store.protos.protos;
nativeBuildInputs = [ pkgs.protobuf ];
# fuse-backend-rs uses DiskArbitration framework to handle mount/unmount on Darwin
buildInputs = lib.optional pkgs.stdenv.isDarwin (commonDarwinDeps ++ pkgs.darwin.apple_sdk.frameworks.DiskArbitration);
};
snix-eval-builtin-macros = prev: {
src = depot.snix.utils.filterRustCrateSrc { root = prev.src.origSrc; };
};
snix-eval = prev: {
src = depot.snix.utils.filterRustCrateSrc rec {
root = prev.src.origSrc;
extraFileset = root + "/proptest-regressions";
};
};
snix-glue = prev: {
src = depot.snix.utils.filterRustCrateSrc {
root = prev.src.origSrc;
};
};
snix-serde = prev: {
src = depot.snix.utils.filterRustCrateSrc { root = prev.src.origSrc; };
};
snix-tracing = prev: {
src = depot.snix.utils.filterRustCrateSrc { root = prev.src.origSrc; };
};
};
# This creates an extraStep in CI to check whether the Cargo.nix file is up-to-date.
mkCrate2nixCheck =
path: # The path to the Cargo.nix to be checked.
let
relCrateRoot = lib.removePrefix "./" (builtins.dirOf (lib.path.removePrefix depot.path.origSrc path));
in
{
label = "crate2nix check for ${relCrateRoot}";
needsOutput = true;
alwaysRun = true;
command = pkgs.writeShellScript "crate2nix-check-for-${lib.replaceStrings [ "/" ] ["-"] relCrateRoot}" ''
(cd $(git rev-parse --show-toplevel)/${relCrateRoot} &&
${depot.tools.crate2nix-generate}/bin/crate2nix-generate &&
if [[ -n "$(git status --porcelain -unormal Cargo.nix)" ]]; then
echo "----------------------------------------------------------------------------------------------------"
echo "Cargo.nix needs to be updated, run 'mg run //tools/crate2nix-generate' in ${relCrateRoot}"
echo "----------------------------------------------------------------------------------------------------"
exit 1
fi
)
'';
};
}