ae4d967288
contrib/ gets the clickhouse patching, the bucket log parsing code and the awscli setup and shell. ops/ gets the machine config itself. Change-Id: If8b8f8cce5ca9c2b4d19e17be9a8b895ac35e84a Reviewed-on: https://cl.snix.dev/c/snix/+/30163 Autosubmit: Florian Klink <flokli@flokli.de> Tested-by: besadii Reviewed-by: Ryan Lahfa <masterancpp@gmail.com>
75 lines
2.3 KiB
Nix
75 lines
2.3 KiB
Nix
# Helper functions for instantiating depot-compatible NixOS machines.
|
|
{ depot, lib, pkgs, ... }@args:
|
|
|
|
let inherit (lib) findFirst;
|
|
in rec {
|
|
# This provides our standard set of arguments to all NixOS modules.
|
|
baseModule = { ... }: {
|
|
nix.nixPath =
|
|
let
|
|
# Due to nixpkgsBisectPath, pkgs.path is not always in the nix store
|
|
nixpkgsStorePath =
|
|
if lib.hasPrefix builtins.storeDir (toString pkgs.path)
|
|
then builtins.storePath pkgs.path # nixpkgs is already in the store
|
|
else pkgs.path; # we need to dump nixpkgs to the store either way
|
|
in
|
|
[
|
|
("nixos=" + nixpkgsStorePath)
|
|
("nixpkgs=" + nixpkgsStorePath)
|
|
];
|
|
};
|
|
|
|
nixosFor = configuration: (depot.third_party.nixos {
|
|
configuration = { ... }: {
|
|
imports = [
|
|
baseModule
|
|
configuration
|
|
];
|
|
};
|
|
|
|
specialArgs = {
|
|
inherit (args) depot;
|
|
};
|
|
});
|
|
|
|
findSystem = hostname:
|
|
(findFirst
|
|
(system: system.config.networking.hostName == hostname)
|
|
(throw "${hostname} is not a known NixOS host")
|
|
(map nixosFor depot.ops.machines.all-systems));
|
|
|
|
rebuild-system = rebuildSystemWith (
|
|
# HACK: use the string of the original source to avoid copying the whole
|
|
# depot into the store just for this
|
|
builtins.toString depot.path.origSrc);
|
|
|
|
rebuildSystemWith = depotPath: pkgs.writeShellScriptBin "rebuild-system" ''
|
|
set -ue
|
|
if [[ $EUID -ne 0 ]]; then
|
|
echo "Oh no! Only root is allowed to rebuild the system!" >&2
|
|
exit 1
|
|
fi
|
|
|
|
echo "Rebuilding NixOS for $HOSTNAME"
|
|
system=$(${pkgs.nix}/bin/nix-build -E "((import ${depotPath} {}).ops.nixos.findSystem \"$HOSTNAME\").system" --no-out-link --show-trace)
|
|
|
|
${pkgs.nix}/bin/nix-env -p /nix/var/nix/profiles/system --set $system
|
|
$system/bin/switch-to-configuration switch
|
|
'';
|
|
|
|
# Systems that should be built in CI
|
|
archivistEC2System = nixosFor depot.ops.machines.archivist-ec2;
|
|
gerrit01System = nixosFor depot.ops.machines.gerrit01;
|
|
public01System = nixosFor depot.ops.machines.public01;
|
|
build01System = nixosFor depot.ops.machines.build01;
|
|
meta01System = nixosFor depot.ops.machines.meta01;
|
|
nixosSnixCache = nixosFor depot.ops.machines.snix-cache;
|
|
|
|
meta.ci.targets = [
|
|
"archivistEC2System"
|
|
"gerrit01System"
|
|
"public01System"
|
|
"build01System"
|
|
"meta01System"
|
|
];
|
|
}
|