91d02d8c84
Most of the ecosystem has moved to this formatter, and many people configured their editors to autoformat it with this formatter. Closes: https://git.snix.dev/snix/snix/issues/62 Change-Id: Icf39e7836c91fc2ae49fbe22a40a639105bfb0bd Reviewed-on: https://cl.snix.dev/c/snix/+/30671 Reviewed-by: Florian Klink <flokli@flokli.de> Tested-by: besadii Autosubmit: Ilan Joselevich <personal@ilanjoselevich.com>
63 lines
1.9 KiB
Nix
63 lines
1.9 KiB
Nix
# This file defines the root of all external dependency imports (i.e.
|
|
# third-party code) in the TVL package tree.
|
|
#
|
|
# There are two categories of third-party programs:
|
|
#
|
|
# 1) Programs in nixpkgs, the NixOS package set. For these, you might
|
|
# want to look at //third_party/nixpkgs (for the package set
|
|
# imports) and //third_party/overlays (for modifications in these
|
|
# imported package sets).
|
|
#
|
|
# 2) Third-party software packaged in this repository. This is all
|
|
# other folders below //third_party, other than the ones mentioned
|
|
# above.
|
|
|
|
{
|
|
pkgs,
|
|
depot,
|
|
localSystem,
|
|
...
|
|
}:
|
|
|
|
{
|
|
# Expose a partially applied NixOS, expecting an attribute set with
|
|
# a `configuration` key. Exposing it like this makes it possible to
|
|
# modify some of the base configuration used by NixOS.
|
|
#
|
|
# This partially reimplements the code in
|
|
# <nixpkgs/nixos/default.nix> as we need to modify its internals to
|
|
# be able to pass `specialArgs`. We depend on this because `depot`
|
|
# needs to be partially evaluated in NixOS configuration before
|
|
# module imports are resolved.
|
|
nixos =
|
|
{
|
|
configuration,
|
|
specialArgs ? { },
|
|
system ? localSystem,
|
|
...
|
|
}:
|
|
let
|
|
eval = import (pkgs.path + "/nixos/lib/eval-config.nix") {
|
|
inherit specialArgs system;
|
|
modules = [
|
|
configuration
|
|
];
|
|
};
|
|
|
|
# This is for `nixos-rebuild build-vm'.
|
|
vmConfig =
|
|
(import (pkgs.path + "/nixos/lib/eval-config.nix") {
|
|
inherit specialArgs system;
|
|
modules = [
|
|
configuration
|
|
(pkgs.path + "/nixos/modules/virtualisation/qemu-vm.nix")
|
|
];
|
|
}).config;
|
|
in
|
|
{
|
|
inherit (eval) pkgs config options;
|
|
system = eval.config.system.build.toplevel;
|
|
# NOTE: This doesn't work because of missing NixOS modules.
|
|
# vm = vmConfig.system.build.vm;
|
|
};
|
|
}
|