6046ff9f25
Included changes: * targeted primary NixOS channel back at `nixos-unstable` * //3p/chicago95: disable new broken symlink check * //tvix: omit unnecessary lifetime clippy recommends * //users/sterni/blipqn: wait a bit for data to arrive in test so it succeeds under load. * //fun/paroxysm: force pkg-config flag of pq-sys by adding a bogus dependency on it. Otherwise, pq-sys will try to use pg_config which does not work correctly in pkgs.libpq at the moment. * //users/flokli/keyboards/dilemma: disable temporarily Change-Id: I6d53bd7bca6886f3457e1f41505e97314f4cd191 Reviewed-on: https://cl.tvl.fyi/c/depot/+/13119 Reviewed-by: tazjin <tazjin@tvl.su> Tested-by: BuildkiteCI Reviewed-by: flokli <flokli@flokli.de> Autosubmit: tazjin <tazjin@tvl.su> Reviewed-by: aspen <root@gws.fyi> Reviewed-by: sterni <sternenseemann@systemli.org>
50 lines
1.6 KiB
Nix
50 lines
1.6 KiB
Nix
# A rendition of everyone's favourite computer theme.
|
|
{ pkgs, ... }:
|
|
|
|
let
|
|
# Chicago95 has no GTK-4 theme (because GTK-4 removed important features that
|
|
# it needs), but there is a project with an approximation.
|
|
#
|
|
# This is a bit of a hack, but I inject that project's GTK-4 theme as if it
|
|
# was a part of Chicago95.
|
|
#
|
|
# This other project is GPL-3.0, under which Chicago95 is also distributed.
|
|
gtk4ProjectSrc = pkgs.fetchFromGitHub {
|
|
owner = "B00merang-Project";
|
|
repo = "Windows-95";
|
|
rev = "055abd7a3608afdcb2ef021732e07020f2b416b2";
|
|
hash = "sha256:1li6wzyn3y09d188xki1h96pmn4xcx2lklfc4rkiq2y2r22wx7kz";
|
|
};
|
|
in
|
|
pkgs.stdenvNoCC.mkDerivation {
|
|
pname = "Chicago95";
|
|
version = "master";
|
|
|
|
src = pkgs.fetchFromGitHub {
|
|
owner = "grassmunk";
|
|
repo = "Chicago95";
|
|
rev = "bdf5cf36a16102aaac297f3de887c601c2b1146f";
|
|
hash = "sha256:11fsy3bam1rhp1292zflvzmf1432z1p0ncwy3601wl2f8rnvfdfm";
|
|
};
|
|
|
|
# The project has a Makefile, but it's broken in all sorts of ways, so we just
|
|
# copy the important stuff manually.
|
|
dontBuild = true;
|
|
installPhase = ''
|
|
mkdir -p $out/share/{icons,fonts,themes,sounds,qt5ct/colors}
|
|
|
|
cp -r Theme/Chicago95 $out/share/themes
|
|
cp -r Icons/* $out/share/icons
|
|
cp -r Cursors/* $out/share/icons
|
|
cp -r Fonts/* $out/share/fonts
|
|
cp Extras/Chicago95_qt.conf $out/share/qt5ct/colors
|
|
|
|
cp -r ${gtk4ProjectSrc}/gtk-4.0 $out/share/themes/Chicago95
|
|
'';
|
|
|
|
# TODO(tazjin): investigate various broken symlinks in $out/share/icons
|
|
dontCheckForBrokenSymlinks = true;
|
|
|
|
meta.license = pkgs.lib.licenses.gpl3;
|
|
}
|
|
|