91d02d8c84
Most of the ecosystem has moved to this formatter, and many people configured their editors to autoformat it with this formatter. Closes: https://git.snix.dev/snix/snix/issues/62 Change-Id: Icf39e7836c91fc2ae49fbe22a40a639105bfb0bd Reviewed-on: https://cl.snix.dev/c/snix/+/30671 Reviewed-by: Florian Klink <flokli@flokli.de> Tested-by: besadii Autosubmit: Ilan Joselevich <personal@ilanjoselevich.com>
41 lines
1.2 KiB
Nix
41 lines
1.2 KiB
Nix
{ lib, ... }:
|
|
let
|
|
# replaces " and \ to \" and \\ respectively and quote with "
|
|
# e.g.
|
|
# a"b\c -> "a\"b\\c"
|
|
# a\"bc -> "a\\\"bc"
|
|
escapeExeclineArg =
|
|
arg: ''"${builtins.replaceStrings [ ''"'' ''\'' ] [ ''\"'' ''\\'' ] (toString arg)}"'';
|
|
|
|
# Escapes an execline (list of execline strings) to be passed to execlineb
|
|
# Give it a nested list of strings. Nested lists are interpolated as execline
|
|
# blocks ({}).
|
|
# Everything is quoted correctly.
|
|
#
|
|
# Example:
|
|
# escapeExecline [ "if" [ "somecommand" ] "true" ]
|
|
# == ''"if" { "somecommand" } "true"''
|
|
escapeExecline =
|
|
execlineList:
|
|
lib.concatStringsSep " " (
|
|
let
|
|
go =
|
|
arg:
|
|
if builtins.isString arg then
|
|
[ (escapeExeclineArg arg) ]
|
|
else if builtins.isPath arg then
|
|
[ (escapeExeclineArg "${arg}") ]
|
|
else if lib.isDerivation arg then
|
|
[ (escapeExeclineArg arg) ]
|
|
else if builtins.isList arg then
|
|
[ "{" ] ++ builtins.concatMap go arg ++ [ "}" ]
|
|
else
|
|
abort "escapeExecline can only hande nested lists of strings, was ${
|
|
lib.generators.toPretty { } arg
|
|
}";
|
|
in
|
|
builtins.concatMap go execlineList
|
|
);
|
|
|
|
in
|
|
escapeExecline
|