90281c4eac
Splits //ops/nixos into: * //ops/nixos.nix - utility functions for building systems * //ops/machines - shared machine definitions (read by readTree) * //ops/modules - shared NixOS modules (skipped by readTree) This simplifies working with the configuration fixpoint in whitby, and is overall a bit more in line with how NixOS systems in user folders currently work. Change-Id: I1322ec5cc76c0207c099c05d44828a3df0b3ffc1 Reviewed-on: https://cl.tvl.fyi/c/depot/+/2931 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org> Reviewed-by: glittershark <grfn@gws.fyi>
53 lines
1.4 KiB
Nix
53 lines
1.4 KiB
Nix
# NixOS module for configuring the simple SMTP relay.
|
|
{ depot, pkgs, config, lib, ... }:
|
|
|
|
let
|
|
inherit (builtins) attrValues mapAttrs;
|
|
inherit (lib)
|
|
concatStringsSep
|
|
mkEnableOption
|
|
mkIf
|
|
mkOption
|
|
types
|
|
;
|
|
|
|
cfg = config.services.depot.smtprelay;
|
|
description = "Simple SMTP relay";
|
|
|
|
# Configuration values that are always overridden. In particular,
|
|
# `config` is specified to always load $StateDirectory/secure.config
|
|
# (so that passwords can be loaded from there) and logging is pinned
|
|
# to stdout for journald compatibility.
|
|
overrideArgs = {
|
|
logfile = "";
|
|
config = "/var/lib/smtprelay/secure.config";
|
|
};
|
|
|
|
# Creates the command line argument string for the service.
|
|
prepareArgs = args:
|
|
concatStringsSep " "
|
|
(attrValues (mapAttrs (key: value: "-${key} '${toString value}'")
|
|
(args // overrideArgs)));
|
|
in {
|
|
options.services.depot.smtprelay = {
|
|
enable = mkEnableOption description;
|
|
args = mkOption {
|
|
type = types.attrsOf types.str;
|
|
description = "Key value pairs for command line arguments";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.services.smtprelay = {
|
|
inherit description;
|
|
script = "${depot.third_party.smtprelay}/bin/smtprelay ${prepareArgs cfg.args}";
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
Restart = "always";
|
|
StateDirectory = "smtprelay";
|
|
DynamicUser = true;
|
|
};
|
|
};
|
|
};
|
|
}
|