aa122cbae7
This CL can be used to compare the style of nixpkgs-fmt against other formatters (nixpkgs, alejandra). Change-Id: I87c6abff6bcb546b02ead15ad0405f81e01b6d9e Reviewed-on: https://cl.tvl.fyi/c/depot/+/4397 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org> Reviewed-by: lukegb <lukegb@tvl.fyi> Reviewed-by: wpcarro <wpcarro@gmail.com> Reviewed-by: Profpatsch <mail@profpatsch.de> Reviewed-by: kanepyork <rikingcoding@gmail.com> Reviewed-by: tazjin <tazjin@tvl.su> Reviewed-by: cynthia <cynthia@tvl.fyi> Reviewed-by: edef <edef@edef.eu> Reviewed-by: eta <tvl@eta.st> Reviewed-by: grfn <grfn@gws.fyi>
52 lines
1.4 KiB
Nix
52 lines
1.4 KiB
Nix
# Configuration for the Gerrit autosubmit bot (//third_party/gerrit-queue)
|
|
{ depot, pkgs, config, lib, ... }:
|
|
|
|
let
|
|
cfg = config.services.depot.gerrit-queue;
|
|
description = "gerrit-queue - autosubmit bot for Gerrit";
|
|
mkStringOption = default: lib.mkOption {
|
|
inherit default;
|
|
type = lib.types.str;
|
|
};
|
|
in
|
|
{
|
|
options.services.depot.gerrit-queue = {
|
|
enable = lib.mkEnableOption description;
|
|
gerritUrl = mkStringOption "https://cl.tvl.fyi";
|
|
gerritProject = mkStringOption "depot";
|
|
gerritBranch = mkStringOption "canon";
|
|
|
|
interval = with lib; mkOption {
|
|
type = types.int;
|
|
default = 60;
|
|
description = "Interval (in seconds) for submit queue checks";
|
|
};
|
|
|
|
secretsFile = with lib; mkOption {
|
|
description = "Path to a systemd EnvironmentFile containing secrets";
|
|
default = "/run/agenix/gerrit-queue";
|
|
type = types.str;
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
systemd.services.gerrit-queue = {
|
|
inherit description;
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${depot.third_party.gerrit-queue}/bin/gerrit-queue";
|
|
DynamicUser = true;
|
|
Restart = "always";
|
|
EnvironmentFile = cfg.secretsFile;
|
|
};
|
|
|
|
environment = {
|
|
GERRIT_URL = cfg.gerritUrl;
|
|
GERRIT_PROJECT = cfg.gerritProject;
|
|
GERRIT_BRANCH = cfg.gerritBranch;
|
|
SUBMIT_QUEUE_TRIGGER_INTERVAL = toString cfg.interval;
|
|
};
|
|
};
|
|
};
|
|
}
|