91d02d8c84
Most of the ecosystem has moved to this formatter, and many people configured their editors to autoformat it with this formatter. Closes: https://git.snix.dev/snix/snix/issues/62 Change-Id: Icf39e7836c91fc2ae49fbe22a40a639105bfb0bd Reviewed-on: https://cl.snix.dev/c/snix/+/30671 Reviewed-by: Florian Klink <flokli@flokli.de> Tested-by: besadii Autosubmit: Ilan Joselevich <personal@ilanjoselevich.com>
88 lines
2.9 KiB
Nix
88 lines
2.9 KiB
Nix
# This file imports the pinned nixpkgs sets and applies relevant
|
|
# modifications, such as our overlays.
|
|
#
|
|
# The actual source pinning happens via niv in //third_party/sources
|
|
#
|
|
# Note that the attribute exposed by this (third_party.nixpkgs) is
|
|
# "special" in that the fixpoint used as readTree's config parameter
|
|
# in //default.nix passes this attribute as the `pkgs` argument to all
|
|
# readTree derivations.
|
|
|
|
{
|
|
depot ? { },
|
|
externalArgs ? { },
|
|
depotOverlays ? true,
|
|
localSystem ? externalArgs.localSystem or builtins.currentSystem,
|
|
crossSystem ? externalArgs.crossSystem or localSystem,
|
|
# additional overlays to be applied.
|
|
# Useful when calling this file in a view exported from depot.
|
|
additionalOverlays ? [ ],
|
|
...
|
|
}:
|
|
|
|
let
|
|
# Arguments passed to both the stable nixpkgs and the main, unstable one.
|
|
# Includes everything but overlays which are only passed to unstable nixpkgs.
|
|
commonNixpkgsArgs = {
|
|
# allow users to inject their config into builds (e.g. to test CA derivations)
|
|
config = (if externalArgs ? nixpkgsConfig then externalArgs.nixpkgsConfig else { }) // {
|
|
allowUnfree = true;
|
|
allowUnfreeRedistributable = true;
|
|
allowBroken = true;
|
|
# Forbids our meta.ci attribute
|
|
# https://github.com/NixOS/nixpkgs/pull/191171#issuecomment-1260650771
|
|
checkMeta = false;
|
|
permittedInsecurePackages = [
|
|
# only used inside tests
|
|
"nix-2.3.18"
|
|
];
|
|
};
|
|
|
|
inherit localSystem crossSystem;
|
|
};
|
|
|
|
# import the nixos-unstable package set, or optionally use the
|
|
# source (e.g. a path) specified by the `nixpkgsBisectPath`
|
|
# argument. This is intended for use-cases where the depot is
|
|
# bisected against nixpkgs to find the root cause of an issue in a
|
|
# channel bump.
|
|
nixpkgsSrc = externalArgs.nixpkgsBisectPath or depot.third_party.sources.nixpkgs;
|
|
|
|
# Stable package set is imported, but not exposed, to overlay
|
|
# required packages into the unstable set.
|
|
stableNixpkgs = import depot.third_party.sources.nixpkgs-stable commonNixpkgsArgs;
|
|
|
|
# Overlay for packages that should come from the stable channel
|
|
# instead (e.g. because something is broken in unstable).
|
|
# Use `stableNixpkgs` from above.
|
|
stableOverlay = _unstableSelf: unstableSuper: {
|
|
# newer trunk fails somewhere within reqwest, trying to read a mystery file
|
|
trunk = stableNixpkgs.trunk;
|
|
};
|
|
|
|
# Overlay to expose the nixpkgs commits we are using to other Nix code.
|
|
commitsOverlay = _: _: {
|
|
nixpkgsCommits = {
|
|
unstable = depot.third_party.sources.nixpkgs.rev;
|
|
stable = depot.third_party.sources.nixpkgs-stable.rev;
|
|
};
|
|
};
|
|
in
|
|
import nixpkgsSrc (
|
|
commonNixpkgsArgs
|
|
// {
|
|
overlays = [
|
|
commitsOverlay
|
|
stableOverlay
|
|
]
|
|
++ (
|
|
if depotOverlays then
|
|
[
|
|
depot.third_party.overlays.tvl
|
|
(import depot.third_party.sources.rust-overlay)
|
|
]
|
|
else
|
|
[ ] ++ additionalOverlays
|
|
);
|
|
}
|
|
)
|