91d02d8c84
Most of the ecosystem has moved to this formatter, and many people configured their editors to autoformat it with this formatter. Closes: https://git.snix.dev/snix/snix/issues/62 Change-Id: Icf39e7836c91fc2ae49fbe22a40a639105bfb0bd Reviewed-on: https://cl.snix.dev/c/snix/+/30671 Reviewed-by: Florian Klink <flokli@flokli.de> Tested-by: besadii Autosubmit: Ilan Joselevich <personal@ilanjoselevich.com>
54 lines
1.3 KiB
Nix
54 lines
1.3 KiB
Nix
# Configuration for the Gerrit autosubmit bot (//ops/gerrit-autosubmit)
|
|
{
|
|
depot,
|
|
pkgs,
|
|
config,
|
|
lib,
|
|
...
|
|
}:
|
|
|
|
let
|
|
cfg = config.services.depot.gerrit-autosubmit;
|
|
description = "gerrit-autosubmit - autosubmit bot for Gerrit";
|
|
mkStringOption =
|
|
default:
|
|
lib.mkOption {
|
|
inherit default;
|
|
type = lib.types.str;
|
|
};
|
|
in
|
|
{
|
|
options.services.depot.gerrit-autosubmit = {
|
|
enable = lib.mkEnableOption description;
|
|
gerritUrl = mkStringOption "https://cl.snix.dev";
|
|
|
|
secretsFile =
|
|
with lib;
|
|
mkOption {
|
|
description = "Path to a systemd EnvironmentFile containing secrets";
|
|
default = config.age.secretsDir + "/gerrit-autosubmit";
|
|
type = types.str;
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
systemd.services.gerrit-autosubmit = {
|
|
inherit description;
|
|
wantedBy = [ "multi-user.target" ];
|
|
wants = [ "network-online.target" ];
|
|
after = [ "network-online.target" ];
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${depot.ops.gerrit-autosubmit}/bin/gerrit-autosubmit";
|
|
DynamicUser = true;
|
|
Restart = "always";
|
|
EnvironmentFile = cfg.secretsFile;
|
|
};
|
|
|
|
environment = {
|
|
GERRIT_URL = cfg.gerritUrl;
|
|
GERRIT_USERNAME = "clbot";
|
|
};
|
|
};
|
|
};
|
|
}
|