aa122cbae7
This CL can be used to compare the style of nixpkgs-fmt against other formatters (nixpkgs, alejandra). Change-Id: I87c6abff6bcb546b02ead15ad0405f81e01b6d9e Reviewed-on: https://cl.tvl.fyi/c/depot/+/4397 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org> Reviewed-by: lukegb <lukegb@tvl.fyi> Reviewed-by: wpcarro <wpcarro@gmail.com> Reviewed-by: Profpatsch <mail@profpatsch.de> Reviewed-by: kanepyork <rikingcoding@gmail.com> Reviewed-by: tazjin <tazjin@tvl.su> Reviewed-by: cynthia <cynthia@tvl.fyi> Reviewed-by: edef <edef@edef.eu> Reviewed-by: eta <tvl@eta.st> Reviewed-by: grfn <grfn@gws.fyi>
51 lines
1.3 KiB
Nix
51 lines
1.3 KiB
Nix
{ lib, pkgs, depot, ... }:
|
|
|
|
# Takes a derivation and a list of binary names
|
|
# and returns an attribute set of `name -> path`.
|
|
# The list can also contain renames in the form of
|
|
# `{ use, as }`, which goes `as -> usePath`.
|
|
#
|
|
# It is usually used to construct an attrset `bins`
|
|
# containing all the binaries required in a file,
|
|
# similar to a simple import system.
|
|
#
|
|
# Example:
|
|
#
|
|
# bins = getBins pkgs.hello [ "hello" ]
|
|
# // getBins pkgs.coreutils [ "printf" "ln" "echo" ]
|
|
# // getBins pkgs.execline
|
|
# [ { use = "if"; as = "execlineIf" } ]
|
|
# // getBins pkgs.s6-portable-utils
|
|
# [ { use = "s6-test"; as = "test" }
|
|
# { use = "s6-cat"; as = "cat" }
|
|
# ];
|
|
#
|
|
# provides
|
|
# bins.{hello,printf,ln,echo,execlineIf,test,cat}
|
|
#
|
|
|
|
let
|
|
getBins = drv: xs:
|
|
let
|
|
f = x:
|
|
# TODO(Profpatsch): typecheck
|
|
let x' = if builtins.isString x then { use = x; as = x; } else x;
|
|
in {
|
|
name = x'.as;
|
|
value = "${lib.getBin drv}/bin/${x'.use}";
|
|
};
|
|
in
|
|
builtins.listToAttrs (builtins.map f xs);
|
|
|
|
|
|
tests = import ./tests.nix {
|
|
inherit getBins;
|
|
inherit (depot.nix) writeScriptBin;
|
|
inherit (depot.nix.runTestsuite) assertEq it runTestsuite;
|
|
};
|
|
|
|
in
|
|
{
|
|
__functor = _: getBins;
|
|
inherit tests;
|
|
}
|