a59e95a287
As soon as you pass in an already-instantiated nixpkgs version, it will cause nixpkgs.hostPlatform etc. to be not applied. This means it's impossible to describe the architecture of a VM closure you're deploying, and have it deviate from the machine you're evaluating from, making it quite hard to deploy that x86_64-linux machine from aarch64-linux (where I'm writing this commit message from). Drop explicitly passing in nixpkgs.path, and set nixpkgs.hostPlatform explicitly for all remaining system configurations in the repository where not already set. Change-Id: Ie2a596e0826da54674b4f02fcd8fed3569fee0a4 Reviewed-on: https://cl.snix.dev/c/snix/+/30104 Autosubmit: Florian Klink <flokli@flokli.de> Tested-by: besadii Reviewed-by: Ryan Lahfa <masterancpp@gmail.com>
66 lines
2.2 KiB
Nix
66 lines
2.2 KiB
Nix
# Helper functions for instantiating depot-compatible NixOS machines.
|
|
{ depot, lib, pkgs, ... }@args:
|
|
|
|
let inherit (lib) findFirst;
|
|
in rec {
|
|
# This provides our standard set of arguments to all NixOS modules.
|
|
baseModule = { ... }: {
|
|
nix.nixPath =
|
|
let
|
|
# Due to nixpkgsBisectPath, pkgs.path is not always in the nix store
|
|
nixpkgsStorePath =
|
|
if lib.hasPrefix builtins.storeDir (toString pkgs.path)
|
|
then builtins.storePath pkgs.path # nixpkgs is already in the store
|
|
else pkgs.path; # we need to dump nixpkgs to the store either way
|
|
in
|
|
[
|
|
("nixos=" + nixpkgsStorePath)
|
|
("nixpkgs=" + nixpkgsStorePath)
|
|
];
|
|
};
|
|
|
|
nixosFor = configuration: (depot.third_party.nixos {
|
|
configuration = { ... }: {
|
|
imports = [
|
|
baseModule
|
|
configuration
|
|
];
|
|
};
|
|
|
|
specialArgs = {
|
|
inherit (args) depot;
|
|
};
|
|
});
|
|
|
|
findSystem = hostname:
|
|
(findFirst
|
|
(system: system.config.networking.hostName == hostname)
|
|
(throw "${hostname} is not a known NixOS host")
|
|
(map nixosFor depot.ops.machines.all-systems));
|
|
|
|
rebuild-system = rebuildSystemWith (
|
|
# HACK: use the string of the original source to avoid copying the whole
|
|
# depot into the store just for this
|
|
builtins.toString depot.path.origSrc);
|
|
|
|
rebuildSystemWith = depotPath: pkgs.writeShellScriptBin "rebuild-system" ''
|
|
set -ue
|
|
if [[ $EUID -ne 0 ]]; then
|
|
echo "Oh no! Only root is allowed to rebuild the system!" >&2
|
|
exit 1
|
|
fi
|
|
|
|
echo "Rebuilding NixOS for $HOSTNAME"
|
|
system=$(${pkgs.nix}/bin/nix-build -E "((import ${depotPath} {}).ops.nixos.findSystem \"$HOSTNAME\").system" --no-out-link --show-trace)
|
|
|
|
${pkgs.nix}/bin/nix-env -p /nix/var/nix/profiles/system --set $system
|
|
$system/bin/switch-to-configuration switch
|
|
'';
|
|
|
|
# Systems that should be built in CI
|
|
gerrit01System = nixosFor depot.ops.machines.gerrit01;
|
|
public01System = nixosFor depot.ops.machines.public01;
|
|
build01System = nixosFor depot.ops.machines.build01;
|
|
meta01System = nixosFor depot.ops.machines.meta01;
|
|
meta.ci.targets = [ "gerrit01System" "public01System" "build01System" "meta01System" ];
|
|
}
|