dd5100acf5
I've checked the new links manually. - //web/tvl: changed the target path of links to the tvix docs since they were moved in r/2378. - //users/aspen/resume: Tvix is no longer //third_party/nix. Change-Id: I419bae1a46bdccc7baa7327215aa2368ffc0f01c Reviewed-on: https://cl.tvl.fyi/c/depot/+/13043 Reviewed-by: aspen <root@gws.fyi> Tested-by: BuildkiteCI Autosubmit: sterni <sternenseemann@systemli.org> Reviewed-by: fogti <fogti+devel@ytrizja.de> Reviewed-by: tazjin <tazjin@tvl.su>
50 lines
1.1 KiB
Nix
50 lines
1.1 KiB
Nix
{ depot, lib, pkgs, ... }:
|
|
|
|
with depot.nix.yants;
|
|
|
|
let
|
|
inherit (builtins) hasAttr filter;
|
|
|
|
config = {
|
|
name = "tazjin's blog";
|
|
baseUrl = "https://tazj.in/blog";
|
|
staticUrl = "https://tazj.in/static/";
|
|
|
|
footer = ''
|
|
<p class="footer">
|
|
<a class="uncoloured-link" href="https://tazj.in">homepage</a>
|
|
|
|
|
<a class="uncoloured-link" href="https://code.tvl.fyi/">code</a>
|
|
</p>
|
|
<p class="lod">ಠ_ಠ</p>
|
|
'';
|
|
};
|
|
|
|
inherit (depot.web.blog) post includePost renderPost;
|
|
|
|
posts = list post (import ./posts.nix);
|
|
|
|
rendered = pkgs.runCommand "tazjins-blog" { } ''
|
|
mkdir -p $out
|
|
|
|
${lib.concatStringsSep "\n" (map (post:
|
|
"cp ${renderPost config post} $out/${post.key}.html"
|
|
) posts)}
|
|
'';
|
|
|
|
in
|
|
{
|
|
inherit rendered config;
|
|
|
|
# Filter unlisted posts from the index
|
|
posts = filter includePost posts;
|
|
|
|
# Generate embeddable nginx configuration for redirects from old post URLs
|
|
oldRedirects = lib.concatStringsSep "\n" (map
|
|
(post: ''
|
|
location ~* ^(/en)?/${post.oldKey} {
|
|
return 301 https://tazj.in/blog/${post.key};
|
|
}
|
|
'')
|
|
(filter (hasAttr "oldKey") posts));
|
|
}
|