f630ce9b93
* Update Snix' verify-lang-tests to 2.28, as 2.25 has been removed from nixpkgs * Update snix/cli integration tests, iso_gnome is called iso_graphical (again?) * Address clippy lints * Regenerate go bindings * Remove grpc-health-check from our overlay, it's long been merged Change-Id: I9d33cabdd3e7065a1f28bcccf4f979f08a456f88 Reviewed-on: https://cl.snix.dev/c/snix/+/30333 Reviewed-by: Ilan Joselevich <personal@ilanjoselevich.com> Autosubmit: Florian Klink <flokli@flokli.de> Tested-by: besadii
56 lines
1.7 KiB
Nix
56 lines
1.7 KiB
Nix
# This overlay is used to make TVL-specific modifications in the
|
|
# nixpkgs tree, where required.
|
|
{ lib
|
|
, depot
|
|
, localSystem
|
|
, ...
|
|
}:
|
|
|
|
self: super:
|
|
depot.nix.readTree.drvTargets {
|
|
# Not available in nixpkgs.
|
|
# Raito: If you want this to disappear, please send the PR yourself.
|
|
alertmanager-irc-relay = super.callPackage depot.third_party.alertmanager-irc-relay.package { };
|
|
|
|
# Avoid builds of mkShell derivations in CI.
|
|
mkShell = super.lib.makeOverridable (
|
|
args:
|
|
(super.mkShell args).overrideAttrs (_: {
|
|
passthru = {
|
|
meta.ci.skip = true;
|
|
};
|
|
})
|
|
);
|
|
|
|
crate2nix = super.crate2nix.overrideAttrs (old: {
|
|
patches = old.patches or [ ] ++ [
|
|
# TODO(Kranzes): Remove in next release.
|
|
./patches/crate2nix-0001-Fix-Use-mkDerivation-with-src-instead-of-runCommand.patch
|
|
# https://github.com/nix-community/crate2nix/pull/301
|
|
./patches/crate2nix-tests-debug.patch
|
|
];
|
|
});
|
|
|
|
evans = super.evans.overrideAttrs (old: {
|
|
patches = old.patches or [ ] ++ [
|
|
# add support for unix domain sockets
|
|
# https://github.com/ktr0731/evans/pull/680
|
|
./patches/evans-add-support-for-unix-domain-sockets.patch
|
|
];
|
|
});
|
|
|
|
# macFUSE bump containing fix for https://github.com/osxfuse/osxfuse/issues/974
|
|
# https://github.com/NixOS/nixpkgs/pull/320197
|
|
fuse =
|
|
if super.stdenv.isDarwin then
|
|
super.fuse.overrideAttrs
|
|
(old: rec {
|
|
version = "4.8.0";
|
|
src = super.fetchurl {
|
|
url = "https://github.com/osxfuse/osxfuse/releases/download/macfuse-${version}/macfuse-${version}.dmg";
|
|
hash = "sha256-ucTzO2qdN4QkowMVvC3+4pjEVjbwMsB0xFk+bvQxwtQ=";
|
|
};
|
|
})
|
|
else
|
|
super.fuse;
|
|
}
|