76258fbfa1
When describing items in the inventory, both in detail and when producing menus from those items, describe not just the item itself but also *where* in the inventory the item is (either in the backpack, or wielded in either or both of the hands). This uses a new InventoryPosition datatype, and a method to get a list of items in the inventory associated with their inventory position. When *removing* items from the inventory (to wield, drop, or eat them), we want to make sure we remove from the right position, so this also introduces a `removeItemAtPosition` method to make that happen correctly. Finally, some of the tests for this stuff was getting really slow - I narrowed this down to runaway arbitrary generation for message Templates, so I've tweaked the Arbitrary instance for that type to generate smaller values. Change-Id: I24e9948adae24b0ca9bf13955602108ca9079dcc Reviewed-on: https://cl.tvl.fyi/c/depot/+/3228 Reviewed-by: grfn <grfn@gws.fyi> Tested-by: BuildkiteCI
43 lines
1.5 KiB
Haskell
43 lines
1.5 KiB
Haskell
module Xanthous.UtilSpec (main, test) where
|
|
|
|
import Test.Prelude
|
|
import Xanthous.Util
|
|
import Control.Monad.State.Lazy (execState)
|
|
|
|
main :: IO ()
|
|
main = defaultMain test
|
|
|
|
test :: TestTree
|
|
test = testGroup "Xanthous.Util"
|
|
[ testGroup "smallestNotIn"
|
|
[ testCase "examples" $ do
|
|
smallestNotIn [7 :: Word, 3, 7] @?= 0
|
|
smallestNotIn [7 :: Word, 0, 1, 3, 7] @?= 2
|
|
, testProperty "returns an element not in the list" $ \(xs :: [Word]) ->
|
|
smallestNotIn xs `notElem` xs
|
|
, testProperty "pred return is in the list" $ \(xs :: [Word]) ->
|
|
let res = smallestNotIn xs
|
|
in res /= 0 ==> pred res `elem` xs
|
|
, testProperty "ignores order" $ \(xs :: [Word]) ->
|
|
forAll (shuffle xs) $ \shuffledXs ->
|
|
smallestNotIn xs === smallestNotIn shuffledXs
|
|
]
|
|
, testGroup "takeWhileInclusive"
|
|
[ testProperty "takeWhileInclusive (const True) ≡ id"
|
|
$ \(xs :: [Int]) -> takeWhileInclusive (const True) xs === xs
|
|
]
|
|
, testGroup "endoTimes"
|
|
[ testCase "endoTimes 4 succ 5"
|
|
$ endoTimes (4 :: Int) succ (5 :: Int) @?= 9
|
|
]
|
|
, testGroup "modifyKL"
|
|
[ testCase "_1 += 1"
|
|
$ execState (modifyKL _1 $ pure . succ) (1 :: Int, 2 :: Int) @?= (2, 2)
|
|
]
|
|
, testGroup "removeFirst"
|
|
[ testCase "example" $
|
|
removeFirst @[Int] (> 5) [1..10] @?= [1, 2, 3, 4, 5, 7, 8, 9, 10]
|
|
, testProperty "the result is the right length" $ \(xs :: [Int]) p ->
|
|
length (removeFirst p xs) `elem` [length xs, length xs - 1]
|
|
]
|
|
]
|