6266c5d32f
Rename my //users directory and all places that refer to glittershark to grfn, including nix references and documentation. This may require some extra attention inside of gerrit's database after it lands to allow me to actually push things. Change-Id: I4728b7ec2c60024392c1c1fa6e0d4a59b3e266fa Reviewed-on: https://cl.tvl.fyi/c/depot/+/2933 Tested-by: BuildkiteCI Reviewed-by: tazjin <mail@tazj.in> Reviewed-by: lukegb <lukegb@tvl.fyi> Reviewed-by: glittershark <grfn@gws.fyi>
41 lines
1.6 KiB
Haskell
41 lines
1.6 KiB
Haskell
--------------------------------------------------------------------------------
|
|
module Xanthous.Entities.Marker ( Marker(..) ) where
|
|
--------------------------------------------------------------------------------
|
|
import Xanthous.Prelude
|
|
--------------------------------------------------------------------------------
|
|
import Data.Aeson
|
|
import Test.QuickCheck
|
|
import qualified Graphics.Vty.Attributes as Vty
|
|
import qualified Graphics.Vty.Image as Vty
|
|
import Brick.Widgets.Core (raw)
|
|
--------------------------------------------------------------------------------
|
|
import Xanthous.Game.State
|
|
import Xanthous.Data.Entities (EntityAttributes(..))
|
|
--------------------------------------------------------------------------------
|
|
|
|
-- | Mark on the map - for use in debugging / development only.
|
|
newtype Marker = Marker Text
|
|
deriving stock (Show, Eq, Ord, Generic)
|
|
deriving anyclass (NFData, CoArbitrary, Function)
|
|
deriving (Semigroup, Monoid, ToJSON, FromJSON, Arbitrary) via Text
|
|
|
|
instance Brain Marker where step = brainVia Brainless
|
|
|
|
instance Entity Marker where
|
|
entityAttributes = const EntityAttributes
|
|
{ _blocksVision = False
|
|
, _blocksObject = False
|
|
, _collision = Stop
|
|
}
|
|
description (Marker m) = "[M] " <> m
|
|
entityChar = const $ "X" & style .~ markerStyle
|
|
entityCollision = const Nothing
|
|
|
|
instance Draw Marker where
|
|
draw = const . raw $ Vty.char markerStyle 'X'
|
|
drawPriority = const maxBound
|
|
|
|
markerStyle :: Vty.Attr
|
|
markerStyle = Vty.defAttr
|
|
`Vty.withForeColor` Vty.red
|
|
`Vty.withBackColor` Vty.black
|